***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Feb 21, 2025                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the data sheet for specification limits.                             *
***********************************************************************
*$
.subckt   PJC7403     drain  gate  source
Lg     gate  g1    2.2n
Ld     drain d1    100p
Ls     source s1   350p
Rs     s1    s2   205u TC=3m
Rg     g1    g2     259.16
M1     d2     g2    s2    s2    DMOS    L=1u   W=1u
.MODEL DMOS PMOS ( KP=5.8  VTO=-1.1  THETA=0  VMAX=1.2e11  ETA=0  LEVEL=3  GAMMA=0.6 )
Rd     d1    d2    190m TC=3m,1u
Dbd    d2    s2    Dbt
.MODEL     Dbt    D(BV=22 TBV1=4.025e-4 TBV2=2.805e-6  M=3.216e-1  CJO=3.444e-11  VJ=3.940e-1 )
Dbody   21   s2    DBODY
.MODEL DBODY  D(IS=7.571e-12   N=1.000  RS=4e-8  EG=0.800  TT=30n  ikf=3.484e-2  tikf=7.361e-3)
Rdiode  d1  21    4.250e-1  TC=-4m
.MODEL   sw    PMOS(VTO=0  KP=10   LEVEL=1)
Maux      g2   c    a    a   sw
Maux2     b    d    g2    g2   sw
Eaux      c    a    d2    g2   1
Eaux2     d    g2   d2    g2   -1
Cox       b    d2   9.180e-11
.MODEL     DGD    D(M=7.280e-1  CJO=9.180e-11   VJ=4.365e-1)
Rpar      b    d2   1Meg
Dgd       d2    a   DGD
Rpar2     d2   a    10Meg
Cgs     g2    s2    6.50734e-11
.ENDS PJC7403 
*$
